MACD 5/MACD 5.bin/workbench/tools/czesc_4/show/show_install

Text File | 1994-12-06 | 3KB | 135 lines

;
; Show Installation Script $VER: Show version 1.0
;

(set @pref-prog "show")
(set @pref-pref "showprefs")

(set @default-dest "SYS:Utilities")
(set @prefs-dest "SYS:Prefs")
(set @install-prefs 1)

(set @choice
    (askchoice
    (prompt "Which version of the Show/ShowPrefs program do you want installed")
    (choices "Show" "Show_020" "Show_020ffp" )
    (help "Choose 'Show' if you have a 68000 or a 68010 processor. "
        "Choose 'Show_020' if you have >=68020 processor and no FPU. "
        "Choose 'Show_020ffp' if you have >=68020 processor AND an FPU. "
        "Aside: There is no _020ffp version of the show program since it is"
        "identical to the _020 version."
    )
    )
)
(if (= 0 @choice)
    ( (set @pref-prog "show") (set @pref-pref "showprefs"))
)
(if (= 1 @choice)
    ( (set @pref-prog "show_020") (set @pref-pref "showprefs_020"))
)
(if (= 2 @choice)
    ( (set @pref-prog "show_020") (set @pref-pref "showprefs_020ffp"))
)

(debug "pref-prog" @pref-prog)
(debug "pref-pref" @pref-pref)

(set @default-dest
    (askdir
    (prompt "Where would you like Show installed?")
    (help "The most likely place to put Show is on your SYS:"
          " partition in the utilities directory."
    )
    (default @default-dest)
    )
)

(set @prefs-dest
    (askdir
    (prompt "Where would you like the Show preferences program installed?")
    (help "The most likely place to put the preferences program is on your SYS:"
          " partition in the prefs directory.")
    (default @prefs-dest)
    )
)

(if ( OR (exists (tackon @default-dest "show")) (exists (tackon @prefs-dest "show")))
    (if
    (askbool
        (prompt "Show already exists. Overwrite")
        (choices "Yes" "No")
        (default 1)
        (help "Press 'Yes' to overwrite previous versions. Press 'No' to abort installation")
    )

    (
        (delete file (tackon @default-dest "show")
             (tackon @default-dest "show.info")
             (tackon @prefs-dest "show")
             (tackon @prefs-dest "show.info")
        )
    )
    (exit (quiet))
    )
)


(copyfiles
    (prompt ("Copying Show to %s" @default-dest))
    (source (tackon (pathonly @icon) @pref-prog))
    (newname "Show")
    (dest @default-dest)
)

(copyfiles
    (source (tackon (pathonly @icon) "Show.info"))
    (dest @default-dest)
)


(copyfiles
    (prompt ("Copying Show Preferences to %s" @prefs-dest))
    (source (tackon (pathonly @icon) @pref-pref))
    (newname "Show")
    (dest @prefs-dest)
)

(copyfiles
    (source (tackon (pathonly @icon) "showprefs.info"))
    (dest @prefs-dest)
    (newname "Show.info")
)

(set @install-prefs
    (askbool
    (prompt "Would you like to install the sample .prefs")
    (help "If you choose yes, show.prefs will be copied to envarc:")
    (default @install-prefs)
    )
)

(if
    (= 1 @install-prefs)
    (
    (copyfiles
        (source (tackon (pathonly @icon) "show.prefs"))
        (dest "envarc:")
    )
    (copyfiles
        (source (tackon (pathonly @icon) "show.prefs"))
        (dest "env:")
    )
    )
)

(message
    "\n"
    ("Show is now installed in your %s directory. "@default-dest)
    ("Please read the accompanying documentation.")
    ("If you have any problems or suggestions write me at [e-mail]")
)

(exit (quiet))